Pancakes — 7 of 12

Chapter 3 - Stirring

[The Measured Liquid extension's default mixing rules don't have a concept for stirring/blending: simply pouring one liquid into another will result in a new liquid. So we'll add some of our own logic for it here.]

A liquid can be stirrable. Raw egg, milky pancake mix, milky raw egg, eggy pancake mix, and pancake batter are stirrable.

A liquid can be well-stirred.

A thing can be stir-inducing. The whisk is stir-inducing.

After examining a fluid container (called the target):

if the target is open and the liquid of the target is stirrable:

if the liquid of the target is well-stirred:

say "The [liquid of the target] is nicely blended.";

otherwise:

say "The [liquid of the target] is not very well-blended. It's rather lumpy, really.".

Stirring is an action applying to two things.

Understand "stir [a fluid container] with [something stir-inducing]" as stirring.

Understand "blend [a fluid container] with [something stir-inducing]" as stirring.

Understand "whisk [a fluid container] with [something stir-inducing]" as stirring.

Understand "beat [a fluid container] with [something stir-inducing]" as stirring.

Understand "mix [a fluid container] with [something stir-inducing]" as stirring.

Check an actor stirring something:

if the noun is empty:

say "But there's nothing in [the noun] to stir!";

stop the action;

if the liquid of the noun is not stirrable:

say "You can't blend the [liquid of the noun] any further.";

stop the action;

if the liquid of the noun is well-stirred:

say "You've already blended the [liquid of the noun] quite superbly.";

stop the action.

Carry out stirring:

say "You vigorously stir the [liquid of the noun] with [the second noun].";

now the liquid of the noun is well-stirred.